Как заставить combobox запоминать последнее значение?

[wolf05632]

Привет еще раз! Есть форма. На форме комбобокс со списком из трех фамилий. Как заставить комбобокс запомнить последнюю выбранную фамилию, чтобы при новом запуске макроса она выводилась по умолчанию? Понимаю, что как-то через static, но метод тыка ничего не дал.((( Помогите, пожалуйста!

[Ципихович Эндрю]

Так, а инициализация формы?

[viter.alex]

В переменную документа, а при запуске макрос опять её читать

[wolf05632]

Ниче не понял... (Три фамилии присваиваются комбобоксу при инициализации формы.(мож надо в чендж?))

Ребят, объясните, пожалуйста, как пятилетнему))

[viter.alex]

Объясняю:

Private Sub UserForm_Initialize()
  ComboBox1.AddItem "Иванов"
  ComboBox1.AddItem "Петров"
  ComboBox1.AddItem "Сидоров"
  
  Dim i As Integer
  On Error Resume Next
  i = CInt(ThisDocument.Variables("ComboboxLastChoice").Value)
  If Err.Number <> 0 Then Err.Clear
  ComboBox1.ListIndex = i
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  Dim var As Variable
  For Each var In ThisDocument.Variables
    If var.Name = "ComboboxLastChoice" Then
      Exit For
    End If
  Next
  If var Is Nothing Then
    ThisDocument.Variables.Add "ComboboxLastChoice", ComboBox1.ListIndex
  Else
    var.Value = ComboBox1.ListIndex
  End If
End Sub

[wolf05632]

Пасиб! Попробую!

ЗЫ: viter.alex
если не затруднит, можете прокомментировать код. Просто мне еще тяжело читать чужие коды...

[viter.alex]

'Процедура инициализации формы
Private Sub UserForm_Initialize()
  'Заполнение выпадающего списка значениями
  ComboBox1.AddItem "Иванов"
  ComboBox1.AddItem "Петров"
  ComboBox1.AddItem "Сидоров"
  
  'Переменная для записи сохранённого индекса выбранного элемента списка
  Dim i As Integer
  'Директива для обработки ошибки. Говорит компилятору, что при появлении
  'ошибки нужно перейти к выполнению следующей строки кода
  On Error Resume Next
  'В переменную i читается значение переменной ComboboxLastChoice из документа,
  'в котором находится макрос. Если такой переменной в документе ещё нет, то
  'произойдёт ошибка. Именно для отлова этой ошибки и предназначается предыдущая
  'директива. Если такая переменная есть, то её значение будет записано в пере-
  'менную i
  i = CInt(ThisDocument.Variables("ComboboxLastChoice").Value)
  'Если была ошибка, то очищаем её значение
  If Err.Number <> 0 Then Err.Clear
  'Восстанавливаем сохранённый индек выбранного элемента списка. Если значение ещё
  'не сохранялось, то будет установлен первый элемент, иначе - сохранённый
  ComboBox1.ListIndex = i
End Sub

'Процедура, вызываемая перед закрытием формы
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
  'Переменная для перебора коллекции переменных документа
  Dim var As Variable
  'Цикл, перебирающий переменные документа в поисках переменной с заданным именем
  For Each var In ThisDocument.Variables
    'Если такая переменная найдена, то выходим из цикла. При этом переменная var
    'будет ссылаться на найденную переменную документа
    If var.Name = "ComboboxLastChoice" Then
      Exit For
    End If
  Next
  'Если переменная var ни на что не ссылается, т.е. переменная с заданным именем не 
  'была найдена, то такую переменную добавляем в переменные документа
  If var Is Nothing Then
    ThisDocument.Variables.Add "ComboboxLastChoice", ComboBox1.ListIndex
  'Если переменная была найдена, то в неё записывается индекс выбранного элемента списка
  Else
    var.Value = ComboBox1.ListIndex
  End If
End Sub

[wolf05632]

Честно говоря, думал, будет легче: типа объявить переменную статик и присвоить ей как-нибудь последнее выбранное значение комбобокса.
СПАСИБО, ОГРОМНОЕ!

[Otradnoe_4D]

Подскажите а как этот код переделать так что бы работало для combobox1, combobox2, combobox3 и так далее)