Ввод-вывод, работа со строками (ассемблер, DOS)

[Журенова Катя]

Ввести с клавиатуры две строки. Сравнить их. Вывести на экран но-мер начала второй строки в первой. ПОМОГИТЕ написать программу.
(тема прерывания, Обработка символьной информации с помощью функций DOS

[Stilet]

Ну со вводом прерываниями не скажу (долго писать) но...
Могу предложить такой пример из MASMLIB для определения вхождения подстроки в строку

	.486
	.model flat,stdcall
	option casemap:none
 ; 	include d:\masm32\include\masm32.inc
;	includelib d:\masm32\lib\masm32.lib
StrLen PROTO :DWORD

.data
 s1 db "qwerty",0
 s2 db "rt",0
.code
InString2 proc startpos:DWORD,lpSource:DWORD,lpPattern:DWORD

  ; ------------------------------------------------------------------
  ; InString searches for a substring in a larger string and if it is
  ; found, it returns its position in eax.
  ;
  ; It uses a one (1) based character index (1st character is 1,
  ; 2nd is 2 etc...) for both the "StartPos" parameter and the returned
  ; character position.
  ;
  ; Return Values.
  ; If the function succeeds, it returns the 1 based index of the start
  ; of the substring.
  ;  0 = no match found
  ; -1 = substring same length or longer than main string
  ; -2 = "StartPos" parameter out of range (less than 1 or longer than
  ; main string)
  ; ------------------------------------------------------------------

    LOCAL sLen:DWORD
    LOCAL pLen:DWORD

    push ebx
    push esi
    push edi

    invoke StrLen,lpSource
    mov sLen, eax           ; source length
    invoke StrLen,lpPattern
    mov pLen, eax           ; pattern length

    cmp startpos, 1
    jge @F
    mov eax, -2
    jmp isOut               ; exit if startpos not 1 or greater
  @@:

    dec startpos            ; correct from 1 to 0 based index

    cmp  eax, sLen
    jl @F
    mov eax, -1
    jmp isOut               ; exit if pattern longer than source
  @@:

    sub sLen, eax           ; don't read past string end
    inc sLen

    mov ecx, sLen
    cmp ecx, startpos
    jg @F
    mov eax, -2
    jmp isOut               ; exit if startpos is past end
  @@:

  ; ----------------
  ; setup loop code
  ; ----------------
    mov esi, lpSource
    mov edi, lpPattern
    mov al, [edi]           ; get 1st char in pattern

    add esi, ecx            ; add source length
    neg ecx                 ; invert sign
    add ecx, startpos       ; add starting offset

    jmp Scan_Loop

    align 16

  ; @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

  Pre_Scan:
    inc ecx                 ; start on next byte

  Scan_Loop:
    cmp al, [esi+ecx]       ; scan for 1st byte of pattern
    je Pre_Match            ; test if it matches
    inc ecx
    js Scan_Loop            ; exit on sign inversion

    jmp No_Match

  Pre_Match:
    lea ebx, [esi+ecx]      ; put current scan address in EBX
    mov edx, pLen           ; put pattern length into EDX

  Test_Match:
    mov ah, [ebx+edx-1]     ; load last byte of pattern length in main string
    cmp ah, [edi+edx-1]     ; compare it with last byte in pattern
    jne Pre_Scan            ; jump back on mismatch
    dec edx
    jnz Test_Match          ; 0 = match, fall through on match

  ; @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

  Match:
    add ecx, sLen
    mov eax, ecx
    inc eax
    jmp isOut

  No_Match:
    xor eax, eax

  isOut:
    pop edi
    pop esi
    pop ebx

    ret

InString2 endp

start:


 invoke InString2,1,ADDR s1,ADDR s2
 ;В EAX находится позиция вхождения строки


ret
end start

[airyashov]

пишите договоримся
airyashov(а)inbox.ru
icq:3(один)7748666

[Min]

Можно было сделать короче, но тогда бы каша получилась.

.model	small
.stack	100h
.data
MaxLen1 db 255                  ;структура....
Len1 db 0                          ;....первой....
string1 db 254 dup (0)         ;...... строки

MaxLen2 db 255                  ;структура....
Len2 db 0                          ;....второй.....
string2 db 254 dup (0)         ;....строки

msgInp1 db 'Input first string:$'
msgInp2 db 'Input second string:$'

msgNo db 'First string not included in second string!$'
msgYes db 'First string included in second string at '
Num db 0,0,0,'$'

.code
;************** Главная процедура *************
start proc
mov	ax,@data
mov	ds,ax
mov	es,ax
xor	ax,ax

call InputProc
call Check

mov	ax,4c00h
int	21h
ret
endp

;*************/Главная процедура**********

;***********Процедура перевода строки**********
NewStr proc
mov dl,10
mov ah,2
int 21h
ret
endp
;***********/Процедура перевода строки**********

;***********Процедура вывода сообщения (в dx-адрес)**********
OutMsg proc
mov ah,9
int 21h
ret
endp
;***********/Процедура вывода сообщения (в dx-адрес)**********

;***********Процедура ввода строки (в dx-адрес начала структуры)***
inputStr proc
mov ah,0Ah
int 21h
ret
endp
;***********/Процедура ввода строки (в dx-адрес начала структуры)***

;**********Процедура ввода********
InputProc proc
mov dx,offset msgInp1                     ;приглашение ввода.....
call OutMsg                                    ;....первой строки
mov dx,offset MaxLen1                     ;ввод......
call inputStr                                    ;....первой строки
call newStr                                     ;перевод каретки на новую строку
mov dx,offset msgInp2                     ;приглашение ввода.....
call OutMsg                                    ;.....второй строки
mov dx,offset MaxLen2                     ;ввод......
call inputStr                                    ;....второй строки
call newStr                                     ;перевод каретки на новую строку
ret
endp
;**********/Процедура ввода********

;**********Процедура проверки**********
Check proc
mov al,Len1
cmp al,Len2
ja CheckNo
mov al,string1[0]
mov di,offset string2
mov bx,di
xor cx,cx
mov cl,Len2
sub cl,Len1
inc cl
CheckLoop:
cld
repne scasb
jne CheckNo
call podCheck
test si,si
jz CheckYes
jmp CheckLoop
CheckYes:
mov dx, offset msgYes
mov ax,di
sub ax,bx
call Convert
jmp exitCheck
CheckNo:
mov dx,offset msgNo
exitCheck:
call OutMsg
ret
endp
;**********/Процедура проверки**********

;**********Процедура подпроверки********
podCheck proc
push cx
push di
dec di
mov si,offset string1
mov cl,Len1
cld
repe cmpsb
jne notPodCheck
xor si,si
jmp exitPodCheck
notPodCheck:
mov si,1
exitPodCheck:
pop di
pop cx
ret
endp
;**********/Процедура подпроверки********

;*********Процедура преобразования байта в символьную форму****
Convert proc
mov si,offset Num+2
mov bx,10
loopConv:
div bl
add ah,'0'
mov [si],ah
xor ah,ah
test al,al
jz exitConv
jmp LoopConv
exitConv:
ret
endp
;*********/Процедура преобразования байта в символьную форму****
end	start