Длительность (продолжительность) видео-файла и Access

[Рысь Комнатная]

Приветствую. Соорудил в акцессе базу для своей коллекции видео. Как программно из файла с видео (и возможно ли в акцессе вообще) вытащить длительность этого самого видео? В проводнике например (в строке состояния) продолжительность отображется. Компонент какой-то к акцессу подключить надо?... в какую сторону вообще рыть? Заранее спасибо

[Allan Stark]

А как вы в базу это дело впихнули ?

[Рысь Комнатная]

В базе только описание.
Для чего это работает: у меня много дисков и файлов с видео, решил привести все в порядок - открываешь базу, ищешь фильм, она тебе выдает - такой-то стеллаж, диск под нумером 15. ну и обложки печатать
Как работает: открываю базу, вставляю в привод дивиди с файлами, нажимаю кнопку и в базу закидываются названия файлов и хочется еще их продолжительность. чтобы вручную не набирать

[Abrakadabra]

Function GetValFileProperty(sFolder As String, sFileName As String, sNameProperty As String) As String
Dim objShellApp, objFolder, objFolderItems, objItem
Dim strResult As String
Dim i%

Set objShellApp = CreateObject("Shell.Application")
Set objFolder = objShellApp.Namespace(CStr(sFolder) )
Set objFolderItems = objFolder.Items()
If (Not objFolderItems Is Nothing) Then
Dim nCount

nCount = objFolderItems.Count
End If
Set objItem = objFolder.ParseName(sFileName)
strResult = ""
For i = -1 To 40
If objFolder.GetDetailsOf(objFolderIte ms, i) = sNameProperty Then
strResult = objFolder.GetDetailsOf(objItem, i)
Exit For
End If
Next
Debug.Print sNameProperty; " = "; strResult, vbInformation
GetValFileProperty = strResult

Set objItem = Nothing
Set objFolderItems = Nothing
Set objFolder = Nothing
Set objShellApp = Nothing

End Function

[EducatedFool]

Сообщение от Abrakadabra

Function GetValFileProperty

Хорошая функция. Не знал про неё раньше...

Вот только почему-то выводит значения не всех свойств:

Sub test_GetDetailsOf()
    sFolder = "E:\Music\": sFileName = "MODERN_TALKING With_a_little_love.mp3"
    Set objFolder = CreateObject("Shell.Application").Namespace(sFolder)
    Set objFolderItems = objFolder.Items()
    Set objItem = objFolder.ParseName(sFileName)
    For i = -1 To 40
        Debug.Print i, objFolder.GetDetailsOf(objFolderItems, i), _
                    objFolder.GetDetailsOf(objItem, i)
    Next
End Sub

Результат:

-1 Тип: Winamp media file
Размер: 8,03 МБ
0 Имя MODERN_TALKING With_a_little_love.mp3
1 Размер 8*226 КБ
2 Тип Winamp media file
3 Изменен 13.09.2008 20:52
4 Дата создания 02.01.2009 14:37
5 Открыт 02.01.2009 14:37
6 Атрибуты A
7 Состояние Подключен

А всё остальное - пусто:

9 Автор
10 Заголовок
11 Тема
12 Категория
13 Страницы
14 Комментарий
15 Авторские права
16 Исполнитель
17 Альбом
18 Год
19 Номер записи
20 Жанр
21 Длительность
22 Качество звука
23 Защита
24 Модель камеры
25 Дата снимка
26 Размеры
27
28
29 Название серии
30 Описание телепрограммы
31
32 Размер аудио образца
33 Частота дискретизации
34 Каналы
35 Производитель
36 Описание
37 Версия файла
38 Название продукта
39 Версия продукта
40 Keywords

И так для всех имеющихся у меня медиафайлов...

Не подскажете, почему так?

(добавлено)
Впрочем, для рисунков кое-что выдаёт...

26 Размеры 256 x 256
27 256 точек
28 256 точек

[raxp]

И так для всех имеющихся у меня медиафайлов...
Не подскажете, почему так?

эти свойства могут быть просто пустыми, гляньте тем же винампом правой кнопкой

[Teslenko_EA]

raxp прав, действительно у разных файлов, некоторые свойства могут быть незаполненными.
to Рысь Комнатная, но тем не менее у всех AVI файлов я смог этим способом "посмотреть" длительность:

Sub checkLongFileAvi()
Const sFlm = "E:\Films\Money.As.Debt.by.Paul.Grignon.avi"
MsgBox "Файл - " + Dir(sFlm) + "  " + longFilm(sFlm)
End Sub
Function longFilm(sVideoFile) As String
    Dim i%, sFile$, oFolder As Object, oFolderItems   As Object, oFile As Object, sFolder
    sFile = Dir(sVideoFile): i = Len(sFile)
    If i = 0 Then Exit Function
    sFolder = Left(sVideoFile, Len(sVideoFile) - i)
    Set oFolder = CreateObject("Shell.Application").Namespace(sFolder)
    Set oFolderItems = oFolder.Items()
    Set oFile = oFolder.ParseName(sFile)
    With oFolder
        longFilm = .GetDetailsOf(oFolderItems, 21) + "  " & .GetDetailsOf(oFile, 21)
    End With
End Function

Евгений.

[Рысь Комнатная]

Спасибо всем огромное за помощь буду сегодня пробовать

[EducatedFool]

Получить достоверную информацию о продолжительности AVI-файлов, можно лишь, выдрав эту информацию из самого файла:

Сообщение от krasin

AVI-файлы являются RIFF-файлами. Грубо говоря, RIFF-файл состоит из нескольких кусочков (chunks), в которых может храниться видео, звук или метаинформация. Кусочек для хранения video имеет заголовок, на основе которого можно узнать длительность как в кадрах, так и в секундах.

Пример кода на Delphi можно найти в этой теме.

Осталось только найти подобный код для VB...

Поищу, если найду - выложу.
(самому надо - макросом из Excel определять продолжительность видеороликов)

[EducatedFool]

Оказывается, не всё так сложно...

Нашел достаточно информации здесь:
http://forum.script-coding.info/viewtopic.php?id=1031
http://forum.codeby.net/index.php?showtopic=20206

Проще всего использовать компонент WindowsMediaPlayer:



Вот весь код:

Private Sub CommandButton1_Click()
    Me.WindowsMediaPlayer1.URL = "D:\LedStudio content\ambulance.avi"
End Sub

Private Sub CommandButton2_Click()
    Me.TextBox1 = "": On Error Resume Next
    With Me.WindowsMediaPlayer1.currentMedia
        Me.TextBox1 = Me.TextBox1 & "Продолжительность ролика:" & vbNewLine
        Me.TextBox1 = Me.TextBox1 & "В секундах: " & .duration & vbNewLine
        Me.TextBox1 = Me.TextBox1 & "В минутах: " & .durationString & vbNewLine
    End With
End Sub