Ошибка при сборке boost на Windows

[gunsoy]

Я ошибся на первом пункте. Помню что boost весил 83МБ, а не 123. Зашёл с Убунту и boost.org подсунул мне Download boost_1_58_0.tar.gz (83.6 MB) версию для Линукса. То есть я пытаюсь собрать Линукс-версию на Windows.

[Пепел Феникса]

вообще от этого не должно сильно зависить, я обычно брал tar.gz когда компилил под винду.
правда я не припомню чтоб вообще исходники зависили от чего, просто разный способ упаковки.

[p51x]

не там бывают строки в юникс/виндовс формате, посмотрите на скрины ясно ж видно

[Пепел Феникса]

честно говоря тестить не хочу пока, он долго распаковывается.
если сегодня ничего не выйдет, то проверю.
нужна именно 58?

[p51x]

та не надо тестить 7з отлично собирается на винде

[_Bers]

у меня своя уже налаженная методика сборки boost под виндовс.
собираю буст компиляторами вижал студии или мингвом32 или мингвом64,

Инструкция по установке boost.

1. Подготовка дистрибутива:

Создаем иерархию каталогов вида:

    archive
     `-- boost_1_57_0
          `-- содержимое дистрибутива

2. Упаковываем архив при помощи архиватора 7z
   Для этого можно использовать вот такой батничек:

    @echo off
    cls

    SET ARCHIVATOR="C:\Program Files\7-Zip\7z"
    SET ARCHIVE=archive

    if not exist %ARCHIVE%   (
        echo ERROR: directory "%ARCHIVE%" not exist
        echo ERROR: abort operation
        exit
   )

   rem запаковать
   cd %ARCHIVE%
   %ARCHIVATOR% a -t7z -mx9 ..\%ARCHIVE%.7z -mmt

===========================================================================

3. Теперь можно приступить к развертыванию boost.
   Для этого копируем (или прокидываем символическую ссылку) 
   полученный выше архив archive.7z в каталог деплоя.
   Туда же копируем скрипт сборки make-boost.bat

   Получится иерархия:

   deploy
    `-- boost
         |--- archive.7z
          `-- make-boost.bat

4. Все настройки сборки сосредоточены в скрипте make-boost.bat
   Если ничего не менять, а сразу запустить скрипт,
   то будет выполнено построение всего boost для debug/release,
   в 64/32 битах для компиляторов cl/mingw

примечание:
такая подготовка нужна по двум причинам:

1.
у меня это стандартная практика деплоя
не только буст, но и другие библиотеки подготавливаются,
а затем разворачиваются по аналогичной схеме.

2.
архиватор 7z c указанными настройками очень хорошо жмет.
а буст весит не мало.

--- продолжение следует ----

[_Bers]

а вот содержимое make-boost.bat

@echo off
cls

rem ---------------------------------------------------------------

set PATH_ENV=%PATH%
set ARCHIVE=archive.7z
set ARCHIVATOR="C:\Program Files\7-Zip\7z"

set NAME_SOURCE_DIRECTORY=boost_1_57_0

set THIS_DIRECTORY=%~dp0
set THIS_DIRECTORY=%THIS_DIRECTORY:~0,-1%

set BUILD_DIRECTORY=%THIS_DIRECTORY%\build
set PATH_DESTINATION=%THIS_DIRECTORY%\external

rem ---------------------------------------------------------------
echo [ BEGIN ]

call :prepare
echo. 

call :make_msvc "32"
call :make_msvc "64"

call :make_mingw "32"

rem требуется 64 битная ос Windows
call :make_mingw "64"

exit /b
rem ---------------------------------------------------------------

:prepare
    if exist %THIS_DIRECTORY%\%NAME_SOURCE_DIRECTORY% ( 
        echo [ Unpacking is not required ]
    ) ELSE ( 
        echo [ Unpacking ] ...
        %ARCHIVATOR% x -y %ARCHIVE%
    ) 

    cd %THIS_DIRECTORY%\%NAME_SOURCE_DIRECTORY%
    if exist b2.exe ( 
        echo [ Bootstraping is not required ] 
    ) ELSE ( 
        call bootstrap.bat 
    )
exit/b

:make_msvc
    set TOOLSET=msvc-12.0
    set PATH_PRODUCT=%PATH_DESTINATION%\msvc2013
    set ADDRESSMODEL=%~1
    call :view
rem    call :build_static_thread
exit/b

:make_mingw

    set TOOLSET=gcc
    set PATH_PRODUCT=%PATH_DESTINATION%\mingw482
    set ADDRESSMODEL=%~1

    set MINGWCOMPILER=%ROOT%\utilities\mingw%ADDRESSMODEL%\bin
    set PATH=%MINGWCOMPILER%;%PATH_ENV%

    call :view
rem    call :build_static_thread
exit/b


rem ------------------------------------------------------

:view
    echo [  source directory ] %THIS_DIRECTORY%\%NAME_SOURCE_DIRECTORY%
    echo [  build directory  ] %BUILD_DIRECTORY%
    echo [ install directory ] %PATH_PRODUCT%\boost
    echo [     libraries     ] %PATH_PRODUCT%\boost\lib%ADDRESSMODEL%
    echo [     compiler      ] %TOOLSET%
    echo [   address model   ] %ADDRESSMODEL%
    echo. 
exit/b

rem ------------------------------------------------------

:build_complete
    echo [ building ]
    b2.exe -j %NUMBER_OF_PROCESSORS% ^
    --build-dir=%BUILD_DIRECTORY% ^
    --prefix=%PATH_PRODUCT%\boost ^
    --libdir=%PATH_PRODUCT%\boost\lib%ADDRESSMODEL% ^
    --build-type=complete ^
    address-model=%ADDRESSMODEL% ^
    toolset=%TOOLSET% ^
    install
exit /b

rem -------------------------------------------
rem пример сборки только библиотеки thread
rem только для статической линковки

:build_static_thread
    echo [ building ]
    b2.exe -j %NUMBER_OF_PROCESSORS% ^
    --build-dir=%BUILD_DIRECTORY% ^
    --prefix=%PATH_PRODUCT%\boost ^
    --libdir=%PATH_PRODUCT%\boost\lib%ADDRESSMODEL% ^
    variant=debug,release ^
    link=static ^
    threading=multi ^
    address-model=%ADDRESSMODEL% ^
    runtime-link=shared ^
    --with-thread ^
    toolset=%TOOLSET% ^
    install
exit /b

rem ------------------------------------------------------
rem пример сборки только библиотеки thread
rem во всех вариантах

:build_complete_thread
    echo [ building ]
    b2.exe -j %NUMBER_OF_PROCESSORS% ^
    --build-dir=%BUILD_DIRECTORY% ^
    --prefix=%PATH_PRODUCT%\boost ^
    --libdir=%PATH_PRODUCT%\boost\lib%ADDRESSMODEL% ^
    --build-type=complete ^
    --with-thread ^
    address-model=%ADDRESSMODEL% ^
    toolset=%TOOLSET% ^
    install
exit /b
rem --------------------------------------------------------------
rem --------------------------------------------------------------
rem --------------------------------------------------------------
rem --------------------------------------------------------------
rem --------------------------------------------------------------

примечание:
разумеется, необходимые компиляторы должны быть.
в батнике нужно указать правильные пути к ним.

например, для мингва это делается в строчках:

set MINGWCOMPILER=%ROOT%\utilities\mingw%ADDRESSMODEL%\bin
set PATH=%MINGWCOMPILER%;%PATH_ENV%

указываем путь к мингву
(32 или 64 в зависимости от значения переменной ADDRESSMODEL)

а затем выставляем переменные среды.

кроме того, функции:

:build_static_thread
и
:build_complete_thread

нужны для того, что бы собирать не весь буст целиком,
а только отдельно взятый компонент boost::thread

дело в том, что прежде чем начать собирать весь буст целиком
полезно собрать отдельно взятый компонент,
что бы убедиться, что все настройки правильные.
и разворот буста происходит как нужно.


приятной сборки.

[gunsoy]

Неделю интернет не работал. Сегодня скачал сперва .7Z, но там сам файл bootstrap.bat находился в другом месте в boost_1_59_0/tools/build/ и его содержимое было не таким каким должно быть http://ipic.su/img/img7/fs/iii.1441117479.jpg То есть там нет set toolset=msvc

Скачал .zip и снова на команде bootstrap.bat проблемы http://ipic.su/img/img7/fs/jjj.1441117330.jpg

Уже тошнит от Виндовса=(

[p51x]

но там сам файл bootstrap.bat находился в другом месте в boost_1_59_0/tools/build/

Там он тоже лежит. Не знаю, что вы качали, но вот передо мной 7з архив буста и в корне есть батник, и он даже собирает. И да в нем есть

:bjam_built

REM Ideally, we should obtain the toolset that build.bat has
REM guessed. However, it uses setlocal at the start and does not
REM export BOOST_JAM_TOOLSET, and I don't know how to do that
REM properly. Default to msvc for now.
set toolset=msvc

Скачал .zip и снова на команде bootstrap.bat проблемы

Продолжайте создавать себе проблемы и мужественно с ними бороться. А ошибка в том, что компилятор не задан или не найден... но этот файл вам не нужен - он сам вызовется, когда надо.

[gunsoy]

Скачал 7z версию 1_58_0 там всё на месте.

А ошибка в том, что компилятор не задан или не найден... но этот файл вам не нужен - он сам вызовется, когда надо.

Сейчас опять такая же фигня вылезает. Подскажите пожалуйста как это исправить? В переменной PATH путь к компилятору указан.