Копирование данных из книги в другую книгу по параметрам

[uniturs]

Добрый день!
Помогите пожалуйста!
Нужен макрос копирования данных из книги свод с листа "Лист1" в книгу инструмент на лист "ИсхДанные_ЦЕНТР" по параметрам : N подразделения, роль, драйвер
в столбец соответствующего месяца , месяцу A2 в файле свод.
Объяснил сумбурно, и если не понятно прокомментирую.
Очень нужна помощь!

[uniturs]

добрый день!
неужели такая сложная задача, что ни кто не может помочи?

[Hugo121]

Сложная.
Честно пытался вчера понять что нужно сделать, ещё сейчас глянул - ничего не понял, сложно очень...
С драйвером не понял, что нужно копировать - не понял.
Разжуйте.
Вообще достаточно протянуть одну формулу, затем заменить на значение. Если примерно правильно понял.

P.S. Хотя смотрю на другом форуме уже разобрались с драйвером...

[uniturs]

я попытался в файлах все обозначить.
в файле Свод ряд параметров: код ГОСБ/ОСБ, Должность, и столбцы : Штатная численность, Вакансии, Кол-во уволенных по собственному желанию.
Надо скопировать данные по этим параметрам в файл Инструмент на лист ИсхДанные_ЦЕНТР
в столбец диапазона N-Y соответствующий данным из ячейки A2 книги Свод, Лист1.
т.е ГОСБ -8, должность-КБП, столбец - Штатная численность = ячейка С4 = 6
надо скопировать в книгу Инструмент , первый лист строка 304, столбец C = ячейка С304, т.к ячейка соответствует параметрам из книги Свод.

Буду очень признателен если поможете.
Решения пока нет и на других форумах!

[Hugo121]

Т.е. критерии:

код ГОСБ/ОСБ
должности
Штатная численность/Вакансии/Кол-во уволенных по собстенному желанию

копировать нужно в Июнь

Достаточно было изначально скопировать данные хотя бы одной строки и указать почему имеено это и именно сюда.
Теперь понятно, легко сделать на словаре. Работаете под Виндой?

[Hugo121]

Вот так вероятно (чуть позаимствовал кода - лень самому писать...):

Option Explicit

Sub tt()
    Dim m$, a(), b(), c(), i&, t$

    With CreateObject("scripting.dictionary"): .comparemode = 1
        With Workbooks("свод.xlsb").Sheets(1)
            m = .Cells(2, 1).Value
            a = .Range(.[F4], .Range("A" & .Rows.Count).End(xlUp)).Value
        End With
        For i = 1 To UBound(a)
            .Item(a(i, 1) & "|" & a(i, 2) & "|Ш") = a(i, 3)
            .Item(a(i, 1) & "|" & a(i, 2) & "|В") = a(i, 4)
            .Item(a(i, 1) & "|" & a(i, 2) & "|К") = a(i, 6)
        Next
        With Workbooks("инструмент.xlsx").Sheets(1)
            i = .Range("C" & .Rows.Count).End(xlUp).Row
            a = .Range(.[C7], .Range("C" & i)).Value
            b = .Range(.[G7], .Range("G" & i)).Value
            c = .Range(.[J7], .Range("J" & i)).Value
        End With
        ReDim d(1 To UBound(a), 1 To 1)

        For i = 1 To UBound(a)
            t = c(i, 1) & "|" & a(i, 1) & "|" & Left(b(i, 1), 1)
            If .exists(t) Then d(i, 1) = .Item(t)
        Next
    End With

    Workbooks("инструмент.xlsx").Sheets(1).Range("N5:Y5").Find(m).Offset(2).Resize(UBound(d)).Value = d

End Sub

Кстати, можно не создавать массив d() пустым, а брать его с листа сразу из нужного столбца, тогда его можно дополнять свежими данными, если вдруг они будут поступать частями.
Ну и поанализировать можно - нет ли изменений в ранее занесённых данных.
Но т.к. такого запроса нет - то так и не делал.

[uniturs]

Спасибо!
Все верно поняли.
Приношу извинения, что изначально не понятно изложил задачу.
Попробую Ваш код. Результат сообщу!
Спасибо!