Учет платежей

[yourself]

Задачка: есть таблица в Excel. В верхней строке - названия месяцев, каждый содержится в двух объединенных ячейках. В следующей строке под названием каждого месяца по две графы: "Начислено" и "Оплачено". В конце таблицы есть графа "Последний месяц оплаты". Она должна показывать, в каком месяце произведена последняя оплата. Алгоритм по идее простенький, но я сломал голову над его реализацией. Не могу понять, как в цикле сделать проход по столбцам с проверкой заполненности ячеек. Помогите плиз
P.S.: Если я непонятно написал словами, посмотрите на вложение...

[SAS888]

Т.к Вы пишите

как в цикле сделать проход по столбцам с проверкой заполненности ячеек

, Значит, как я понял, нужно сделать с помощью VBA. Посмотрите вложение. Запустите макрос "Mes".

[IgorGO]

или на формулах. см.вложение.

[дмидми]

'Перед первым запуском макроса:
'1. Выделить ячейку "Январь".
'2. "Правка -- Перейти... -- Выделить -- текущую область".
'3. "Вставка -- Имя -- Создать...", флажок только "в строке выше".
'
'Поскольку это только пример, то
'при запуске макроса лист с таблицей должен быть активен.

Sub LastPaymentMonth()
    Const JanName = "Январь"
    Const MonthsCount = 6&
    Const LastPaymentMonthName = "Месяц_последней_оплаты"
    Const HeaderRowsCount = 2&
    Const MinPayment = 0.00005

    Dim iJan As Long, jJan As Long, jLPM As Long, j As Long
    Dim r As Range, c As Range, v

    'Осмотреться в отсеках!

    With Range(JanName)
        iJan = .Row - 1&
        jJan = .Column
    End With
    jLPM = Range(LastPaymentMonthName).Column
    
    With Cells(iJan, jJan).CurrentRegion
        Set r = Range(Cells(iJan + HeaderRowsCount, jLPM), _
            Cells(.Rows(.Rows.Count).Row, jLPM))
    End With

    'Собственно работа

    For Each c In r.Cells
        v = Empty
        For j = MonthsCount - 1 To 0& Step -1&
            'Проверка "> MinPayment" вместо IsEmpty()
            '- на случай, если в ячейке будет не константа, а формула
            If Cells(c.Row,  j * 2& + jJan + 1&) > MinPayment Then
                v = Cells(iJan,  j * 2& + jJan)
                Exit For 'j
            End If
        Next 'j
        c = v
    Next 'c
End Sub

[ZORRO2005]

Предложу еще пару решений:

[yourself]

Всем большое спасибо Буду сидеть и разбирать примеры