Возможно ли убрать заголовок и обводку вокруг UserForm

[Mag1str]

Здравствуйте.
Помогите пожалуйста.
Необходимо сделать программу с авторским дизайном
Имеется обычная пользовательская форма. Она будет замощена специальным рисунком с дизайном.
Смысл в том что вид ужасно портит само окно Windows. То есть строка заголовка (где кнопки свернуть,развернуть окно и закрыть). И обводка вокруг формы. Если видели интерфейс OS X то знаете, что там вокруг окна нет обводки.
Существует ли возможность избавиться от этого.
Спасибо.

[Ципихович Эндрю]

это конечно не ответ на Ваш вопрос, ответ очень рядом, он у меня был, забыл куда записал

•Для того, чтобы убрать кнопку Закрыть, представляющую собой небольшой крестик, расположенный в правом углу заголовка формы, достаточно скопировать весь нижеприведённый код в модуль нужной формы. А также делает недоступным пункт Close в системном меню, которое отображается при правом клике по заголовку окна
Кусок ниже вставлять вверху формы

Private Declare Function FindWindow _ 
        Lib "user32.dll" Alias "FindWindowA" ( _ 
        ByVal lpClassName As String, _ 
        ByVal lpWindowName As String) As Long 
Private Declare Function GetWindowLong _ 
        Lib "user32.dll" Alias "GetWindowLongA" ( _ 
        ByVal hWnd As Long, _ 
        ByVal nIndex As Long) As Long 
Private Declare Function SetWindowLong _ 
        Lib "user32.dll" Alias "SetWindowLongA" ( _ 
        ByVal hWnd As Long, _ 
        ByVal nIndex As Long, _ 
        ByVal dwNewLong As Long) As Long 
Кусок ниже вставлять в раздел Initialize
Private Sub UserForm_Initialize() 
    Dim ihWnd As Long, iStyle As Long 

    ihWnd = FindWindow(vbNullString, Me.Caption) 
    iStyle = GetWindowLong(ihWnd, -16&) 
    SetWindowLong ihWnd, -16&, iStyle And Not &H80000 
End Sub

Если найдёте ответ выложите пжл

[Mag1str]

Ок. Спасибо попробую

[Mag1str]

Да... Кнопки убрались а вот заголовок и сама обводка вокруг окна остались...

[viter.alex]

Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Const GWL_STYLE = (-16)
Private Const WS_BORDER As Long = &H800000
Private Const WS_CAPTION As Long = &HC00000

Public Sub ChangeWindow(f As UserForm)
  Dim hwnd As Long
  Dim retval As Long
  hwnd = FindWindow("ThunderDFrame", f.Caption)
  If hwnd <> 0 Then
    retval = SetWindowLong(hwnd, GWL_STYLE, GetWindowLong(hwnd, GWL_STYLE) And WS_BORDER)
  End If
  If retval = 0 Then MsgBox "Fail"
End Sub

Private Sub UserForm_Initialize()
  ChangeWindow Me
End Sub

Вот так убирается граница окна с заголовком. В принципе, с помощью API можно и картинку красиво положить в фон, и форму сделать полупрозрачной ну и прочие вкусности. Только стоит ли оно того?

[Mag1str]

viter.alex
Большое спасибо.

[bati4eli]

Такой вопрос..
эта функция реально помогает, но только на windows aero, если установить обычную тему в windows, то обводка окна сохраняется пока не растянешь её.
=(