выводе на экран строки сопровождение звукового сигнал

[ChestIotVaga]

помогите скажите что не так я хотел сделать при выводе на экран строки сопровождение звукового сигнал но что то не работает выводиться строка а звука нет помогите прошу

.MODEL small
.STACK 100h

.DATA
    msg DB 'Hello, world!', 0Ah, 0Dh, '$'

.CODE
    start:
        mov ax, @data
        mov ds, ax

        ; выводим строку символов на экран
        lea dx, msg
        mov ah, 09h
        int 21h

        ; генерируем звуковой сигнал
        mov al, 10010000b
        out 43h, al
        mov ax, 800
        out 42h, al
        mov al, ah
        out 42h, al
        in al, 61h
        or al, 00000011b
        out 61h, al

        ; ждем 500 миллисекунд
        mov cx, 0BB80h
        mov dx, 0
        mov ah, 86h
        int 15h

        ; останавливаем звуковой сигнал
        in al, 61h
        and al, 11111100b
        out 61h, al

        mov ah, 4Ch
        int 21h
    end start

[macomics]

1) Команда должна содержать указание на чтение и запись двух байт, а также для генерации звука нужен режим 1 или 3

        mov al, 10110110b ; используем режим 3, значит при чтении в циклах задержки должен быть тот же режим
        out 43h, al
        mov dx, 800 ; Сохраним настройку для процедуры ожидания (см. ниже)
        mov cx, 100 ; звуковой сигнал 100 мс
        mov al, dl
        out 42h, al
        mov al, dh
        out 42h, al

2) Задержку лучше сделать на том же таймере

; DX = параметр настройки таймера; CX - Время ожидания, мс
;0.840336 * dx = обнуление раз в  672.2688 мкс
        push bx
        push dx
        mov ax, cx
        mov cx, dx
        mov dx, 50000
        mov bx, 42017 ; = 0.840336 * 50000 = 42016.80
        mul dx ; время, мс * 50000 = dx:ax
        div bx ; dx:ax / 42017 = ax
        mov dx, 1000
        mul dx ; ax * 1000 = время, мкс (dx:ax)
        div cx ; время, мкс (dx:ax) / количество интервалов по 0.840336 мкс
        mov bx, 1000
        mov cx, ax ; = количество интервалов для ожидания заданного количества мс
        pop dx
WAITLOOP:
        dec bx ; этот цикл нужен для задержки между опросами таймера, чтобы не выдавать на него кучу команд быстрее, чем работает его кварцевый генератор
        jnz WAITLOOP
        mov bx, 1000
        mov al, 10000110b ; Важно. Не надо изменять режим работы таймера, если хотите прочитать его счетчик
        out 43h, al
        in al, 42h
        mov ah, al
        in al, 42h
        cmp ax, dx
        mov dx, ax
        jc WAITLOOP ; таймер еще не обнулен
        loop WAITLOOP ; таймер обнулен, считаем количество
        pop bx
; когда насчитали нужное количество обнулений - прошла требуемая по времени задержка
; можно отключить таймер
        in al, 61h
        and al, -4
        out 61h, al

[ChestIotVaga]

уже исправил спасибо) не могил бы мне помочь ещё по одному вопросу