Разбивка текста на части

[viter.alex]

Сообщение от Алекс14

Старался как можно подробнее.

Лучше пример файла приложите, который должен получиться.

[Алекс14]

вот собственно
Только там дурацкие кавычки <<>> я заменю на "" кнокой поиска и замены в текстовом редакторе.

[Sasha_Smirnov]

А чего ж вам сразу не разбить текст на закавыченные фрагменты по 1000±10 знаков?

ПС: ворд не тупит — а следует своим настройкам. Смотрите рис. или используйте

Sub Макрос()
Options.AutoFormatAsYouTypeReplaceQuotes = False
End Sub

[viter.alex]

Вот так:

Sub Quote1000()
  Dim i As Long 'счётчик символов
  Dim c As Long 'счётчик замен
  Dim delim As String 'Вставляемый разделитель
  Dim InsertAfter As Boolean
  Dim DlgResult As Integer
  
  delim = ChrW(34) & vbCr & ChrW(34)
   
  DlgResult = MsgBox("Если Кавычка попадёт в середину слова, вставить её после этого слова?" & vbCr & "Нажмите ""Нет"", чтобы вставить кавычку перед словом.", vbYesNoCancel + vbDefaultButton1)
  Select Case DlgResult
    Case vbYes
      InsertAfter = True
    Case vbNo
      InsertAfter = False
    Case vbCancel
      Exit Sub
  End Select
  
  Application.ScreenUpdating = False
  ActiveDocument.StoryRanges(wdMainTextStory).InsertBefore ChrW(34)
  For i = 1000 To ActiveDocument.StoryRanges(wdMainTextStory).Characters.Count Step 1000
    ActiveDocument.Range(i + Len(delim) * c, i + Len(delim) * c).Select
    With Selection
      If InsertAfter Then
        .MoveEnd wdWord
        .Collapse wdCollapseEnd
        If .Characters.First.Previous.Text = " " Then .MoveLeft
      Else
        .MoveStart wdWord, -1
        .Collapse wdCollapseStart
      End If
      .TypeText delim
    End With
    c = c + 1
  Next
  
  Application.ScreenUpdating = True
  
  MsgBox ("Работа завершена. " & "Вставлено " & c & " пар кавычек.")
End Sub

[Sasha_Smirnov]

Интервалы по ≈1000 знаков (с пробелами) обрубал перед словом. Т. е. в программе Quote1000 выбрал «Нет».

[Алекс14]

Sasha_Smirnov, нашел кнопку и заменил.
Теперь вставляет кавычки как надо. Спасибо.
Последний пост со статистикой не понял.

viter.alex, это именно то, что мне и нужно.
Огромное спасибо, что помогли.

[Sasha_Smirnov]

В посте #25 я исследовал отклонения от 1000 знаков при разбивке текста. Ведь в любом анализе важно знать, насколько он точен.

[Алекс14]

Сообщение от Sasha_Smirnov

В посте #25 я исследовал отклонения от 1000 знаков при разбивке текста. Ведь в любом анализе важно знать, насколько он точен.

Ясно.
10 букоф

[Sasha_Smirnov]

Э, нет! 16. Нормально?