Как заменить «елочки» кавычки на „запятые“

[olegspectr]

Спасибо за совет по макросу, но он к сожалению не работает. Нужно отлаживать. Как будет время посмотрю.
Если есть еще предложения - пишите. Все таки у исходного компьютера все работает без макроса.

[Sasha_Smirnov]

Без макроса придётся лезть в «потроха» автозамены (что по силам наверно лишь её разработчикам).

Вот более лояльный макрос, с защитой от „пустого места”:

Sub QQ() 'Берёт слово в кавычки (назначить функциональной клавише или сочетанию клавиш)
Const L = "„", R = "“"  'левые и правые кавычки требуемого начертания

If ActiveDocument.ComputeStatistics(wdStatisticWords) = 0 Then MsgBox "Нет слов!": Exit Sub

    Select Case Selection 'смотря где курсор (точнее, что за ним)
    Case Space(1), L, R
        
        With Selection                      'работаем со словом, предшествующим курсору
        MsgBox ".Words(1): " & .Words(1)
            If InStr(.Words(1), R) = 0 And .Words(1).Characters.Last <> R Then
                .Words(1) = L & Trim(.Words(1)) & R
                'Взяли в кавычки слово, после которого стоял курсор (если ещё не закавычено)
                .Extend R 'растянули выделение до правых кавычек (R) включительно
                .Collapse wdCollapseEnd 'сбросили выделение вправо
                .TypeText " "           'добавили пробел
            End If
        End With
        
    Case Else
    
        With Selection.Words(1).Previous    'работаем со словом, предшествующим курсору
        MsgBox ".Words(1): " & .Words(1)
            If InStr(.Words(1), R) = 0 And .Words(1).Characters.Last <> R Then
                .Words(1) = L & Trim(.Words(1)) & R
                'Взяли в кавычки слово, после которого стоял курсор (если ещё не закавычено)
                Selection.Extend R 'растянули выделение до правых кавычек (R) включительно
                Selection.Collapse wdCollapseEnd 'сбросили выделение вправо
                Selection.TypeText " "
            End If
        End With
        
    End Select
End Sub

Сообщение от Sasha_Smirnov

набрал слово, решил закавычить и жми клавишу, на которой этот макрос

Попробуйте, пожалуйста, кому не лень.

И более привычно (одно нажатие — одни кавычки) работает в документе ещё 1 код (пока сырой).

[olegspectr]

Кавычки макрос присваивает последнему слову, не удобно. Нужно нажать - появились кавычки открывающиеся, написать предложение, нажать появились закрывающиеся кавычки. Как- то так. Т.е. выполнить проверку на наличие кавычек открывающихся по тексту.

[Sasha_Smirnov]

Sub Q_wedding() 'ставим на F5 (что на ноутбуке не требует удерживать клавишу fn)
Const S = "[ 0-9A-Za-zА-яЁё" & vbCr & "]"
Dim Q As String * 1
    
With Selection.Characters
        If Selection.Range.End = 0 Then '(Это отдельный случай: в начале документа)
            Q = Chr(132) 'открывающие кавычки-лапки
        Else
            If .Last Like S Then Q = Chr(132) Else Q = Chr(147)
            If .Last.Previous Like "[A-Za-zА-яЁё]" Then Q = Chr(147) 'закрывающие
        End If
    SendKeys Q 'печать кавычек (открывающих либо закрывающих, смотря по курсору)
End With
    
End Sub

Вообще в первом варианте (QQ) я имел в виду фразы типа «Когда-то выходил журнал „Крококодил“», где лапчатые кавычки являются внутренними.

И при наборе закавыченной фразы использовал бы автоформат при вводе (окно на рисунке), а слово внутри её — заключал бы в кавычки одним (!) тычком по F5.

[olegspectr]

Последний вариант приемлемый. Спасибо.
Но он не работает под word 2003. Выдает ошибку на SendKeys Q. Нужно разбираться.

[Sasha_Smirnov]

Олег, возможно, поможет параметр True через запятую после SendKeys.

Также вместо SendKeys попробуйте Selection.Typetext — пашет?

Сообщение от olegspectr

Статьи я все эти перечитал - нет ответа. Нужна именно автоматизация и именно к shift+2.

Я в пятницу установил и испытал на моём рабочем Word 2003 — по сравнению с домашним (где Windows 10) разницы не заметил. Только важно учитывать, что SendKeys шлёт свой аргумент в активное окно — и это должен быть сам документ (а, например, не редактор кода).

[olegspectr]

Проверил все работает. В принципе устраивает такой вариант.
Макрос повесить на одну клавишу и все.
Спасибо огромное.
Осталась загадка не разгаданой как сделали эту подмену на компьютере, что я указывал. Но видимо идей больше не осталось. Столько было просмотров и никто не предложил больше ничего. Спасибо всем.

[Sasha_Smirnov]

Сейчас, на 18:00, просмотров 561 (я был тут 343-м). Испытание порадовало! О багах сообщайте.

Сообщение от Sasha_Smirnov

Весы похожи на кустик черники или брусники.