Как вивисть значения регистра AX??

[yura_zb]

ideal
model small
stack 100h
dataseg
	fin	db	'Результат виконання: $'
	A dw 2
	B dw 0
	C dw 24
codeseg
start:
	mov	ax,@data
	mov	ds,ax
	mov	ah,09h
	mov	dx,offset fin
	int		21h
	
	mov ax, offset A
	mov cx, offset C
	mov bx, offset B
	
	mov dx, 3
	mul ax
	mul dx
	sub cx, ax
	add bx, 2
	mov ax, bx
	mul ax
	mul bx
	sub ax, 4
	xchg ax, cx
	div cx
	
		
	mov	ax,4c00h
	int	21h
end	start

Как из етого кода вивисти значения AX???

[Serge_Bliznykov]

так пойдёт?

; tasm /m showdc2.asm
; tlink /t /x showdc2.obj

; программа (в формате DOS COM), выводящей на экран десятичное значение регистра ax:

.MODEL Tiny
.CODE
ORG	100h

Start:

		std                    ; Устанавливаем ОБРАТНЫЙ порядок записи
		lea	di,StringEnd-1 ; ES:DI = последний символ строки String

		mov	ax,Number2      ; Заносим в AX число для перевода

; Начинаем перевод числа AX в строку
		mov	cx,10          ; Задаемся делителем CX = 10
Repeat:
		xor	dx,dx          ; Обнуляем DX (для деления)
		div	cx             ; Делим DX:AX на CX (10),
                                       ; Получаем в AX частное, в DX остаток
		xchg	ax,dx          ; Меняем их местами (нас интересует остаток)
		add	al,'0'         ; Получаем в AL символ десятичной цифры
		stosb                  ; И записываем ее в строку
		xchg	ax,dx          ; Восстанавливаем AX (частное)
		or	ax,ax          ; Сравниваем AX с 0
		jne	Repeat         ; Если не ноль, то повторяем

; Теперь осталось вывести строку на экран
		mov	ah,9
		lea	dx,[di+1]      ; Заносим в DX адрес начала строки
		int	21h            ; Выводим ее на экран

		int	20h            ; Выходим из программы

String		db	5 dup (?),'$'  ; Резервируем 5 байт для строки
StringEnd	=	$-1            ; Указывает на символ '$'
Number2         dw      12345

END		Start

[yura_zb]

спасибо!!!!