Помогите исправить ошибку компилятора tasm

[K1905]

Абель Питер - Ассемблер и программирование для IBM PC
http://lib.rin.ru/doc/i/5734p104.html
page 60,132

TITLE   TABSRCH (COM) Табличный поиск
CODESG  SEGMENT PARA 'Code'
        ASSUME  CS:CODESG,DS:CODESG,ES:CODESG
        ORG     100H
BEGIN:  JMP     SHORT MAIN
; -----------------------------------------------
STOKNIN DW      '23'
STOKTAB DB      '05','Excavators'
        DB      '08','Lifters   '
        DB      '09','Presses   '
        DB      '12','Valves    '
        DB      '23','Processors'
        DB      '27','Pumps     '
DESCRN  10      DUP(?)
; -----------------------------------------------
MAIN    PROC    NEAR
        MOV     AX,STOKNIN      ;Загрузить номер элемента
        XCHG    AL,AH
        MOV     CX,06           ;Число элементов в таблице
        LEA     SI,STOKTAB      ;Начальный адрес таблицы
A20:
        CMP     AX,[SI]         ;Сравнить элементы
        JE      A30             ;Если равны - выйти,
        ADD     SI,12           ;  нет - следующий элемент
        LOOP    A20
        CALL    R10ERR          ;Элемент в таблице не найден
        RET
A30:
        MOV     CX,05           ;Длина описания элемента
        LEA     DI,DESCRN       ;Адрес описания элемента
        INC     SI
        INC     SI              ;Выделить описание
        REP MOVSW               ;  из таблицы
        RET
MAIN    ENDP
;
R10ERR  PROC
;               <Вывод сообщения об ошибке>
        RET
R10ERR  ENDP

CODESG  ENDS
        END     BEGIN

Все материалы с подленника,но компилятор TASM ошибку
Turbo Assembler Version 4.1 Copyright (c) 1988, 1996 Borland International

Assembling file: 29.asm
**Error** 29.asm(15) Illegal instruction
**Error** 29.asm(31) Undefined symbol: DESCRN
Error messages: 2
Warning messages: None
Passes: 1
Remaining memory: 452k

_____
Код программы нужно выделять (форматировать) тегами [CODE] (читать FAQ)
Модератор

[p51x]

DESCRN 10 DUP(?)

Не указано 10 чего. db 10? dw 10? ...

[Serge_Bliznykov]

очень трудно изучать ассемблер по книжке с опечатками..
надеюсь, что эта мелкая опечатка - единственная!

вместо

DESCRN  10      DUP(?)

должно быть указание типа выделяемой памяти.
например

DESCRN  DB  10 DUP(?)

[K1905]

Большое спасибо за подсказку.В этом учебнике много таких опечаток,но с ними справлялся сам.Мне уже через три месяца будет 70 лет,но несмотря на преклонный возраст,занимаюсь изучением ассемблера самостоятельно.
Николай.

[R71MT]

Сообщение от K1905

Мне уже через три месяца будет 70 лет

Круто!!! Снимаю шляпу!

[K1905]

Абель Питер - Ассемблер и программирование для IBM PC
http://lib.rin.ru/doc/i/5734p104.html
page 60,132

TITLE   NMSORT  (EXE) Ввод и сортировка имен
; -----------------------------------------------
STACKSG   SEGMENT  PARA STACK 'Stack'
        DW      32 DUP(?)
STACKSG   ENDS
; -----------------------------------------------
DATASG  SEGMENT PARA 'Data'
NAMEPAR LABEL   BYTE            ;Имя списка параметров:
MAXNLEN DB      21              ; макс. длина
NAMELEN DB      ?               ; число введенных символов
NAMEFLD DB      21 DUP(' ')     ; имя

CRLF    DB      13, 10, '$'
ENDADDR DW      ?
MESSG1  DB      'Name?', '$'
NAMECTR DB      00
NAMETAB DB      30 DUP(20 DUP(' ')) ;Таблица имен
NAMESAV DB      20 DUP(?), 13, 10, '$'
SWAPPED DB      00
DATASG ENDS 
; ----------------------------------------------- 
CODESG SEGMENT PARA 'Code' 
BEGIN PROC FAR 
ASSUME CS:CODESG,DS:DATASG,SS:STACKSG,ES:DATASG 
PUSH DS 
SUB AX,AX 
PUSH AX 
MOV AX,DATASG 
MOV DS,AX 
MOV ES,AX 
CLD 
LEA DI,NAMETAB 
CALL Q10CLR ;Очистить экран 
CALL Q20CURS ;Установить курсор 
A20LOOP: 
CALL B10READ ;Ввести имя с клавиатуры 
CMP NAMELEN,00 ;Есть ли еще имена? 
JZ A30 ; нет - идти на сортировку 
CMP NAMECTR,30 ;Введено 30 имен? 
JE A30 ; да - идти на сортировку 
CALL D10STOR ;Записать имя в таблицу 
JMP A20LOOP 
A30: ;Конец ввода имен 
CALL Q10CLR ;Очистить экран 
CALL Q20CURS ; и установить курсор 
CMP NAMECTR,01 ;Введено менее 2 имен? 
JBE A40 ; да - выйти 
CALL G10SORT ;Сортировать имена 
CALL K10DISP ;Вывести результат на экран 
A40: RET ;Завершить программу 
BEGIN ENDP 
; Ввод имен с клавиатуры? 
; ---------------------- 
B10READ PROC 
MOV AH,09 
LEA DX,MESSG1 ;Вывести текст запроса 
INT 21H 
MOV AH,0AH 
LEA DX,NAMEPAR ;Ввести имя 
INT 21H 
MOV AH,09 
LEA DX,CRLF ;Вывести CRLF 
INT 21H 

MOV BH,00 ;Очистить поле после имени 
MOV BL,NAMELEN ;Получить счетчик символов 
MOV CX,21 
SUB CX,BX ;Вычислить оставшуюся длину 
B20: 
MOV NAMEFLD[BX],20H ;Установить символ пробела
INC BX 
LOOP B20 
RET 
B10READ ENDP 
; Запись имени в таблицу: 
; ---------------------- 
D10STOR PROC 
INC NAMECTR ;Число имен в таблице 
CLD 
LES SI,NAMEFLD 
MOV CX,10 
REP MOVSW ;Переслать имя в таблицу 
RET 
D10STOR ENDP 
; Сортировка имен в таблице: 
; ------------------------- 
G10SORT PROC 
SUB DI,40 ;Установить адреса останова 
MOV ENDADDR,DI 
G20: 
MOV SWAPPED,00 ;Установить начало 
LEA SI,NAMETAB ; таблицы 
G30: 
MOV CX,20 ;Длина сравнения 
MOV DI,SI 
ADD DI,20 ;Следующее имя для сравнения 
MOV AX,DI 
MOV BX,SI 
REPE CMPSB ;Сравнить имя со следующим 
JBE G40 ; нет перестановки 
CALL H10XCHG ; перестановка 
G40: 
MOV SI,AX 
CMP SI,ENDADDR ;Конец таблицы? 
JBE G30 ; нет - продолжить 
CMP SWAPPED,00 ;Есть перестановки? 
JNZ G20 ; да - продолжить, 
RET ; нет - конец сортировки 
G10SORT ENDP 
; Перестановка элементов таблицы: 
; ------------------------------ 
H10XCHG PROC 
MOV CX,10 
LEA DI,NAMESAV 
MOV SI,BX 
REP MOVSW ;Сохранить меньший элемент 

MOV CX,10 
MOV DI,BX 
REP MOVSW ;Переслать больший элемент 
; на место меньшего 
MOV CX,10 
LEA SI,NAMESAV 
REP MOVSW ;Переслать сохраненный 
; элемент на место большего 
MOV SWAPPED,01 ;Признак перестановки 
RET 
H10XCHG ENDP 
; Вывод на экран отсортированные имена: 
; ------------------------------------ 
K10DISP PROC 
LEA SI,NAMETAB 
K20: 
LEA DI,NAMESAV ;Начальный адрес таблицы 
MOV CX,10 
REP MOVSW 
MOV AH,09 
LEA DX,NAMESAV 
INT 21H ;Вывести на экран 
DEC NAMECTR ;Это последний элемент? 
JNZ K20 ; нет - повторить цикл, 
RET ; да - выйти 
K10DISP ENDP 
; Очистка экрана: 
; -------------- 
Q10CLR PROC 
MOV AX,0600H 
MOV BH,61H ;Цвет (07 для ч/б) 
SUB CX,CX 
MOV DX,184FH 
INT 10H 
RET 
Q10CLR ENDP 
; Установка курсора: 
; ----------------- 
Q20CURS PROC 
MOV AH,02 
SUB BH,BH 
SUB DX,DX ;Установить курсор в 00,00 
INT 10H 
RET 
Q20CURS ENDP 

CODESG ENDS 
END BEGIN

C:\TASM\BIN>TASM.EXE 33.ASM
Все материалы с подлинника,но компилятор TASM выдает ошибку
Turbo Assembler Version 4.1 Copyright (c) 1988, 1996 Borland International

Assembling file: 33.ASM
**Error** 33.ASM(81) Operand types do not match
Error messages: 1
Warning messages: None
Passes: 1
Remaining memory: 449k

С оформлением программного кода, как описать,пожалуйста поясните на моем конкретном обращении.С уважением Николай.

_____
Код программы нужно выделять (форматировать) тегами [CODE] (читать FAQ)
Модератор

[Serge_Bliznykov]

думаю, что вместо

LES SI,NAMEFLD

должно быть

LEA SI,NAMEFLD

[K1905]

Большое спасибо! Все правильно,заменив команду LES на LEA,tasm ошибки не показал.Похоже,что кто переводил эту книгу,не знает или плохо владеет знанием программирования потому, что во многих программах найдены ошибки или это сделано,чтобы пользователь находил эти ошибки и самостоятельно их устранял.Николай.