Команда леа

[Lamo]

Всем доброго времени суток. Имеется код программы под Fasm, в котором я не понимаю как работает: lea eax,[_otvets-IDYES*5+eax+eax*4]. Изучать начал недавно, поэтому пинать не надо.

Вот код:

format PE GUI 4.0
entry start ;Точка входа в программу
INCLUDE 'win32ax.inc'
INCLUDE 'encoding\win1251.inc'
INCLUDE 'api\user32.inc'
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
section '.data' data readable writable
_da     db 'Да?',0
_otvets db 'Нет!',0
        db 'Да!',0
_name   db 'Обманщик v.2.0',0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
section '.code' code readable executable
start:
        invoke  MessageBox,0,_da,_name,MB_YESNOCANCEL
        cmp     eax,IDCANCEL
        jz      CANCEL_PRESSED
        lea     eax,[_otvets-IDYES*5+eax+eax*4] ; а ну-ка, шевельните извилиной
        invoke  MessageBox,0,eax,_name,MB_OK
        jmp     start
CANCEL_PRESSED:
        invoke  ExitProcess,0
section '.idata' import data readable writeable
library kernel32,'KERNEL32.DLL',user32,'USER32.DLL'
include 'API\KERNEL32.INC'

Заранее всем спасибо.

[Пепел Феникса]

совмещение двух обработчиков в одном.(для IDNO и IDYES)
если в eax IDYES то мы получим адрес сообщения "Нет!"
иначе сообщения "Да!"(IDNO-IDYES=1 что при умножении на 5 и выдаст смещение к букве Д относительно _otvets)

[kogemrka]

Как я понял, тебе нужно объяснить смысл команды lea.

В данном случае эта команда просто выполняет арифметические действия: умножает eax на пять (eax+eax*4) и прибавляет значение (_otvets-IDYES*5) (которое вычисляется ещё на стадии ассемблирования). Результат этих действий помещается в регистр EAX

Для того, чтобы понять вообще,что делает lea нужно вникнуть в такую штуку, как косвенная адресация (и различные её разновидности).
В кратце:
Прямая адресация - это когда мы напрямую указываем адрес, с которого нужно взять данные. Пример:

mov ax, variable

Косвенная адресация - это когда адрес, с которого нам нужно получить данные, записан в регистре. Пример:

mov ax, [bx]

Существуют сложные методы косвенной адресации, например:
по базе со сдвигом:

mov ax, [bx+2]

Или по базе с индексированием:

mov ax, [bx+si+2]

В этих случаях ассемблер перед пересылкой будет сам вычислять адрес, складывая (и умножая) регистры.

Команда lea позволяет вычислить адрес, указанный таким способом и сохранить вычисленное значение в регистре. Иногда lea используют для быстрых арифметических вычислений - эта команда занимает мало байт, быстро работает и в отличии от ADD не изменяет флаги процессора.

Все способы косвенной адресации и условия их применения описаны, к примеру, в книге Зубкова "Ассемблер для DOS, Windows и Unix". Там буквально несколько страничек прочесть нужно.

Если у тебя нет этой книги - пиши в личку,я пришлю её тебе в электронном виде. Впрочем, найти её не проблема - CHM версия лежит в интернете буквально на каждом шагу