Определить, сколько строк текста в ячейке таблицы

[CrySTaL]

Здравствуйте.
Ситуация такая:
1. В макросе формируется текст произвольной длины
2. В макросе текст вставляется в ячейку заданной в шаблоне таблицы
3. Если текст не помещается в ячейку, то Word разбивает его на несколько строк

Требуется все не поместившиеся строки перенести в следующий ряд таблицы ( пишу макрос для формирования спецификации по ГОСТ )

У меня пока не получилось даже определить - поместился ли текст в ячейку, или появились переносы ..

[Скрипт]

Попробуйте Information(wdFirstCharacterLineNum ber) использовать для определения количество строк текста в одной ячейке:

Sub Procedure_1()

    Dim rRangeStart As Word.Range, rRangeEnd As Word.Range
    Dim lStart As Long, lEnd As Long
    
    'Создаём два диапазона в оперативной памяти компьютера.
    'Эти диапазоны относятся к ячейке, где находится курсор.
    Set rRangeStart = Selection.Cells(1).Range
    Set rRangeEnd = Selection.Cells(1).Range
    
    'Изменяем диапазон "rRangeEnd", чтобы потом
    'можно было сделать нужное действие.
    rRangeEnd.MoveEnd Unit:=wdCharacter, Count:=-1
    
    'Изменяем диапазон "rRangeEnd".
    'Теперь диапазон представляет собой конец диапазона "rRangeEnd".
    rRangeEnd.Collapse Direction:=wdCollapseEnd
    
    'wdFirstCharacterLineNumber - даёт порядковый номер строки в документе.
    lStart = rRangeStart.Information(wdFirstCharacterLineNumber)
    lEnd = rRangeEnd.Information(wdFirstCharacterLineNumber)
    
    'Чтобы увидеть результат: View - Immediate Window.
    Debug.Print lEnd - lStart + 1
    
End Sub

[CrySTaL]

Спасибо. Полезный совет.
А есть ли способ обратиться к коллекции строк в ячейке?

[Скрипт]

А есть ли способ обратиться к коллекции строк в ячейке?

не знаю.


С меньшим количеством действий.
Код перемещает курсор в конец первой ячейки первой таблицы.

Sub Procedure_1()

    Dim rEnd As Word.Range
    Dim oTable As Word.Table
    
    Set oTable = ActiveDocument.Tables(1)
    
    Set rEnd = _
        ActiveDocument.Range(Start:=oTable.Cell(1, 1).Range.End - 1, _
        End:=oTable.Cell(1, 1).Range.End - 1)
    
    rEnd.Select
    
End Sub

[viter.alex]

никакой коллекции строк не существует. Нужно перемещаться по строкам, одновременно отслеживая смену ячейки

[Казанский]

Делал подобное: http://www.cyberforum.ru/vba/thread724457.html

[Скрипт]

Можно ещё использовать Information(wdVerticalPositionRelat iveToPage).
Ниже код работает, если курсор находится в ячейке таблицы.
Результат выводится в View - Immediate Window.

Sub Procedure_1()

    Dim myRange As Word.Range
    
    '1. В оперативной памяти компьютера создаём диапазон "myRange",
        'который содержит информацию о фрагменте документа, где находится ячейка,
        'в которой находится курсор.
    'Т.к. выделено может быть несколько ячеек, то в скобках - Cells(1) -
        'нужно указать порядковый номер ячейки. Даже если выделена
        'всего одна ячейка всё-равно нужно указать в скобках порядковый номер.
    Set myRange = Selection.Cells(1).Range
    
    '2. Смотрим расстояние между началом диапазона и верхом страницы.
    'Хоть в коде и не указано, что нас интересует начало, но
        'анализируется именно начало.
    Debug.Print myRange.Information(wdVerticalPositionRelativeToPage)
    
    '3. В оперативной памяти компьютера изменяем диапазон "myRange".
    'Если в программе Word включить режим отображения непечатаемых
        'символов, то в каждой ячейке видно кружок - знак ячейки.
    'Создаём диапазон, который будет собой представлять место
        'в документе перед знаком ячейки.
    'Если не делать "- 1", то диапазон представляет собой место
        'в документе уже в следующей ячейке.
    myRange.SetRange Start:=myRange.End - 1, End:=myRange.End - 1
    
    '4. Смотрим, на каком расстоянии от верха страницы находится
        'конец диапазона ячейки.
    Debug.Print myRange.Information(wdVerticalPositionRelativeToPage)

End Sub