Макрос "дописывает" не нужные параметры

[DrManual]

Здравствуйте, All
Прошу помощи.

Есть -Word 2003 SP3

Задача форматирования включала изменение выравнивания текста. Записал рекордером:

Sub ReplaceAlignment()
'
' ReplaceAlignment
' 19.02.2009 AlexeyTerekhov
'
Selection.Find.ClearFormatting
With Selection.Find.ParagraphFormat
.SpaceBeforeAuto = False
.SpaceAfterAuto = False
.Alignment = wdAlignParagraphLeft
.OutlineLevel = wdOutlineLevelBodyText
End With
Selection.Find.ParagraphFormat.Bord ers.Shadow = False
Selection.Find.Replacement.ClearFor matting
With Selection.Find.Replacement.Paragrap hFormat
.SpaceBeforeAuto = False
.SpaceAfterAuto = False
.Alignment = wdAlignParagraphJustify
.OutlineLevel = wdOutlineLevelBodyText
End With
Selection.Find.Replacement.Paragrap hFormat.Borders.Shadow = False
With Selection.Find
.Text = ""
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = True
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

При записи отрабатывается замена на ура. НО!!
При повторном использовании макроса обнаруживаю, что в свойствах окна "Find" появляются параметры "Границы"



Данный кошмар повторяется на двух совершенно разных машинах. При этом листинг макроса без изменений.

Что не так?

[Sasha_Smirnov]

Не хватало очистки формата (что и покал далее Алекс).

Раз уж совершенствуем код, то давайте уберём лишнее.

Sub AlignmentText()
' AlignmentText' 

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find.ParagraphFormat
        .Alignment = wdAlignParagraphLeft
        .OutlineLevel = wdOutlineLevelBodyText
    End With
    With Selection.Find.Replacement.ParagraphFormat
        .Alignment = wdAlignParagraphJustify
        .OutlineLevel = wdOutlineLevelBodyText
    End With

    Selection.Find.Execute Replace:=wdReplaceAll 'вот тут и выполняется (Execute) вышеопределённая замена'

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
End Sub

[viter.alex]

Просто сохраняются условия последнего поиска/замены.
Допиши в конце макроса

Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting

и будет тебе счастье.
Первая строка очищает форматирование для искомого текста, вторая — для текста замены.
В макросе эти строки есть. Они в макрорекордере всегда предваряют поиск/замену, чтобы старые условия не влияли на происходящее.
В диалоговом окне это аналогично тому, что ты поставишь курсор в нужное поле и нажмешь кнопку «Снять форматирование»


P.S. Для оформления кода пользуйся тегом [code][/code], а не [quote][/quote]

[DrManual]

Спасибо за реальную помощь!

В конечном варианте код выглядит (и работает) так:

Sub AlignmentText()
'
' AlignmentText 
' 
'
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find.ParagraphFormat
        .Alignment = wdAlignParagraphLeft
        .OutlineLevel = wdOutlineLevelBodyText
    End With
    With Selection.Find.Replacement.ParagraphFormat
        .Alignment = wdAlignParagraphJustify
        .OutlineLevel = wdOutlineLevelBodyText
    End With
    With Selection.Find
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
End Sub

Еще раз спасибо!

[viter.alex]

Лучшая благодарность — это когда следуют твоим советам.