Переход из реального режима в защищённый

[BVOG]

Есть прога:

		jmp GO
	GDT:
		NULL_DESCR db 8 dup(0)
		DATA_DESCR db 0ffh, 0ffh, 00h, 00h, 00h, 10011010b, 11001111b, 00h
		CODE_DESCR db 0ffh, 0ffh, 00h, 00h, 00h, 10010010b, 11001111b, 00h
		VIDEO_DESCR db 0ffh, 00h, 080h, 0bh, 10010010b, 01000000b, 00h
		GDT_size equ $-GDT
		
		GDTR dw GDT_size-1
		dd ?
	GO:
		lgdt [fword ptr GDTR]
		
		in al, 092h
		or al, 2
		out 092h, al
		
		cli
		
		in al, 070h
		or al, 080h
		out 070h, al
		
		mov eax, cr0
		or al, 1
		mov cr0, eax
		
		;?????????
		
	PMODE:
		jmp $

Работает код нормально, но нужно перейти с дальним джампом, а как лучше сделать расчитать положение PMODE в памяти и прыгнуть туда, или загнать в дескриптор кода положение PMODE? Нужен код, пример высчитать положение PMODE. У меня появиля вариант через lea ax, [PMODE], но я в нём не уверен. Что посоветуете, желательно с примером. Компилятор TASM.
Извините за предыдущую тему, браузер барахлит)

[rpy3uH]

трудно воспользоваться гуглем?
вот здесь всё есть, есть исходники и примеры и всё на TASM. читай на здоровье

[BVOG]

Есть маленький ньюанс: файл комовский и не должен содеражать разные сегменты и стэки. Я поэтому и спрашиваю.

[rpy3uH]

вычисляй адрес относительно регистра CS.
я писал COM программу переводящую процессор в защищённый режим на FASM, скинул бы, но он на ноутбуке, а его рядом нет.
в общем, примерно так.
xor eax, eax
mov ax, cs
shl eax, 4
add eax, PMODE
EAX = абсолютный адрес метки PMODE
но нельзя забывать что код после метки PMODE тоже идёт комовский, и все метки в нём тоже будут относительно CS, получается что в коде защищённого режима тоже придётся вычислять адреса меток по правилам реального режима

[Пепел Феникса]

для начала вопрос, а вы, ТС, не будете знать по какой базе грузится у вас код?
(я у ся в загрузчике переход был начиная со 0:7e00, и использую org задал базу, и все шикарно, никаких поправок не делал после перехода(правда ядро внешнее и на С, но у него уже своя база? дп и не суть, так как всетаки часть загрузчика учавствовала в защищенном режиме, подготавливая стек и данные))
использовал fasm

[BVOG]

Прога грузиться booter-ом по адресу [01000h:0100h] + в самой проге org 100h. И у меня загрузчик только читает данные в память, переход в защищённый режим находится в самой проге.

[Пепел Феникса]

вам точно нужен столь высокий адрес?
или может сделать чтоб одна часть перешла в PM, потом скопировала по адресу другую часть, а та другая часть уже выравнена как надо...

ну, а в данном случае придется делать по принципу смещений, как и предлагали.

[BVOG]

Тогда нужно из защищённого режима считать с флопика без прерывания.

[rpy3uH]

я делал что-то в этом духе (FASM)

		xor		eax,eax
		mov		ax, cs
		shl		eax,4
		add		eax, PROTECTED_MODE_ENTRY_POINT
		mov		[ENTRY_OFF],eax

		xor		eax,eax
		mov		ax,cs
		shl		eax,4
		add		ax, GDT

		mov		dword [GDTR+2],eax
		lgdt		fword [GDTR]

		cli
		in		al,70h
		or		al,80h
		out		70h,al

		mov		eax,cr0
		or		al,1
		mov		cr0,eax

		db		66h
		db		0EAh			
ENTRY_OFF	dd		PROTECTED_MODE_ENTRY_POINT		      
		dw		CODE_SELEKTOR

align 8
GDT:
;дескрипторы................

label GDTR fword
		dw		GDT_size-1		
		dd		?		

use32

USER_PM_CODE_BASE_ADDRESS EQU 0100000h

PROTECTED_MODE_ENTRY_POINT:
                      ;загрузка регистров DS, SS, ES

		call delta
         delta:
		pop ebx
		add ebx, USER_PM_CODE_START-delta

		mov	       esi, ebx
		mov	       edi, USER_PM_CODE_BASE_ADDRESS
		mov	       ecx, USER_PM_CODE_SIZE
		rep	       movsb

		mov	       eax,USER_PM_CODE_BASE_ADDRESS
		jmp	       eax

USER_PM_CODE_START:
ORG USER_PM_CODE_BASE_ADDRESS

		include 'PM_CODE.ASM';

USER_PM_CODE_END:

т.е. принцип такой:
в файле PM_CODE.ASM мы пишем код который работает в защищённом режиме и используем в нём метки не заботясь о возможных глюках связанный с COM файлами.
После перехода в защищённый режим программа просто переносит код из файла PM_CODE.ASM по адресу USER_PM_CODE_BASE_ADDRESS вот и всё.

и вообще я рекомендую использовать FASM при написании подобных программ.

[Пепел Феникса]

я тоже самое и имел в виду
да и кстати, чтение с флопика много где описано с сорцами причем
(даж у нас на форуме видел, правда на С)

Грузин, а что за 70h порт?