Ввод пароля

[danmen]

Здравствуйте, я столкнулся с такой проблемой:

а мне надо что бы вводимый пароль засвечивался звездочками=)
p.s. пароль вводится при нажатии кнопки, по этому коду:

Private Sub Кнопка10_Click()

B = InputBox("Введите пароль для входа")
If B = "1234" Then
DoCmd.OpenForm "даные"
Else
MsgBox "Пароль введен неправильно, попытайтесь еще.."
Exit Sub
End If
End Sub

[LittleFatCat]

Доброго времени суток!

С помощью InputBox такой пароль ввести нельзя. Нужно использовать свою форму ввода с текстовым полем и кнопкой. Тут есть варианты - печатать белым по белому, воспользоваться маской "Пароль", сохранять введенные символы в переменную, а текст в окне подменять звездочками (на событие ИЗМЕНЕНИЕ)

[danmen]

спасиб за ответ)

[R Dmitry]

Сообщение от LittleFatCat

Доброго времени суток!

С помощью InputBox такой пароль ввести нельзя. Нужно использовать свою форму ввода с текстовым полем и кнопкой. Тут есть варианты - печатать белым по белому, воспользоваться маской "Пароль", сохранять введенные символы в переменную, а текст в окне подменять звездочками (на событие ИЗМЕНЕНИЕ)

Ни когда не говорите, то в чем сами до конца не уверены.

В модуль:

Option Compare Database
Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Public Declare Function SetTimer& Lib "user32" _
(ByVal hWnd&, ByVal nIDEvent&, ByVal uElapse&, ByVal lpTimerFunc&)
Public Declare Function KillTimer& Lib "user32" _
(ByVal hWnd&, ByVal nIDEvent&)
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Public Const RDG As Long = &H5000&
Public Const PASCHAR = &HCC
Private CaptionText As String

Public Sub TimerProc(ByVal hWnd&, ByVal uMsg&, ByVal idEvent&, ByVal dwTime&)
Dim myHwnd As Long
myHwnd = FindWindowEx(FindWindow(vbNullString, CaptionText), 0, "Edit", "")
Call SendMessage(myHwnd, PASCHAR, 42, 0)
KillTimer Application.hWndAccessApp, idEvent
End Sub
Public Function InputBoxRD(Prompt As String, Caption As String) As String
CaptionText = Caption
SetTimer Application.hWndAccessApp, RDG, 10, AddressOf TimerProc
InputBoxRD = InputBox(Prompt, Caption)
End Function

и проверка

Sub Test_message()
MsgBox InputBoxRD(" ", "R Dmitry_pasword")
End Sub

теперь вот такой хитрый INPUTBOX можно использовать не создавая дополнительных форм.

Дмитрий

[SuperMicha]

Зачем такие сложности???
Создаете инбокс, в режиме конструктора выделяете его мышкой, потом в окне свойств -> данные -> маска ввода пишете слово "пароль" и всё!