Ошибка в функции WorksheetFunction

[ольгаг]

Здравствуйте Уважаемые программисты!
Подскажите пожалуйста, есть макрос, который должен выводить число уникальных значений в диапазоне A1:A10, но он у меня не работает. Подскажите где может быть ошибка в формуле?

Sub проба()
Dim a
a = Application.WorksheetFunction.Sum(1 / Application.WorksheetFunction.Count If([A1:A10], [A1:A10]))
MsgBox a
End Sub

Спасибо.

[Казанский]

Ошибка в попытке разделить 1 на массив в VBA. В формуле листа работает:

Sub проба()
Dim a
a = Evaluate("SUM(1/COUNTIF(A1:A10,A1:A10))")
MsgBox a
End Sub

[ольгаг]

Спасибо Вам большое!

[ольгаг]

У меня появился еще один вопрос, подскажите пожалуйста, если диапазон задан не конкретно, а в виде "ActiveSheet.Range("B6", Cells(Rows.Count, "B").End(xlUp))" (т.е. диапазон начинающийся от ячейки B6 и до последней заполненной ячейки в столбце B), как исправить мой макрос:

Sub проба()
Dim a,b
Set b = ActiveSheet.Range("B6", Cells(Rows.Count, "B").End(xlUp))
a = Evaluate("SUM(1/COUNTIF(b,b))")
MsgBox a
End Sub

Спасибо.

[The_Prist]

a = Evaluate("SUM(1/COUNTIF(" & b.Address & "))")

[ольгаг]

Спасибо большое! Все получилось. Вот итоговый код:
Sub проба()
Dim a, b
Set b = ActiveSheet.Range("B6", Cells(Rows.Count, "B").End(xlUp))
a = Evaluate("SUM(1/COUNTIF(" & b.Address & "," & b.Address & "))")
MsgBox a
End Sub

[Казанский]

Как выяснили недавно, метод Evaluate чувствителен к стилю ссылок. Т.е. если установить стиль ссылок R1C1, то этот макрос не сработает. Следует формировать адрес с учетом стиля ссылок:

Sub проба()
Dim a, b
b = Range("B6", Cells(Rows.Count, "B").End(xlUp)).Address(, , Application.ReferenceStyle)
a = Evaluate("SUM(1/COUNTIF(" & b & "," & b & "))")
MsgBox a
End Sub

Если адрес встречается в формуле не один раз, для удобства и наглядности можно делать так:

a = Evaluate(Replace("SUM(1/COUNTIF(~,~))", "~", b))

[ольгаг]

Спасибо большое за ценную информацию!

[The_Prist]

Сообщение от Казанский

Как выяснили недавно, метод Evaluate чувствителен к стилю ссылок. Т.е. если установить стиль ссылок R1C1, то этот макрос не сработает. Следует формировать адрес с учетом стиля ссылок:

b = Range("B6", Cells(Rows.Count, "B").End(xlUp)).Address(, , Application.ReferenceStyle)

Алексей, да, про этот момент я забыл. Надо не забывать учитывать в будущем.