Вывод результата!

[Аделинкка]

По-моему,так первый вариант проще реализовать))
На яблоках почти все понятно,спасибо большое.

[Ulex]

По-моему,так первый вариант проще реализовать))

Нет, не проще. Это я на яблоках всё упростил. А если бы у вас и в знаменателе могло получаться дробное число? А если у вас вообще все входные числа типа флоат, как тогда. Тогда всё несколько усложнилось бы.
А сложность с сопроцессором заключается только в выводе данных. Тут вам уже предлагали использовать fpu.lib из состава масм32. Можно ещё использовать msvcrt - библиотеку, но она должна быть в системе.

P.S.
Кстати, вы обратили внимание, что у вас формула в заголовке вообще не соответствует тому, что вычисляется.
((a+b)*c-24)/ac-1 это не то же самое, что ((a+b)*c-24)/(ac-1)

[Аделинкка]

Могу ответить только по поводу заголовка,опечаталась,исправила на ((a+b)*c-24)/(ac-1).
А сопроцессор не много не разобралась..надо подключить библиотеку, и опять чуток помучиться с выводом результата?

[Ulex]

А сопроцессор не много не разобралась..надо подключить библиотеку, и опять чуток помучиться с выводом результата?

Надо как обычно, подключить библиотеку, взять книжку, прочитать про архитектуру сопроцессора, понять что такое стек сопроцессора и зачем, почитать справочник по командам сопроцессора, понять с какими типами данных он может работать....ну и написать программу, вобщем всё как всегда.

.386
.model flat,stdcall
option casemap:none
include C:\masm32\INCLUDE\WINDOWS.INC
include C:\masm32\INCLUDE\KERNEL32.INC 
include C:\masm32\INCLUDE\USER32.INC
include C:\masm32\INCLUDE\fpu.inc

includelib C:\masm32\lib\user32.lib
includelib C:\masm32\lib\kernel32.lib 
includelib C:\masm32\lib\fpu.lib 

.DATA
title_1 DB "((a+b)*c-24)/(ac-1)",0	;((20+30)*40-24)/(20*40-1)=2.378
R db 12 dup (0)
Avar	dd 20
Bvar	dd 30
Cvar	dd 40
Const1	dd 24
Const2	dd 1
Result	dt 0

.CODE
START: 
finit
fild	dword ptr [Avar]
fiadd	dword ptr [Bvar]
fimul	dword ptr [Cvar]
fisub	dword ptr [Const1]
fild	dword ptr [Avar]
fimul	dword ptr [Cvar]
fisub	dword ptr [Const2]
fdiv
fstp	[Result]
invoke	FpuFLtoA, addr [Result], 8, addr [R], SRC1_REAL or SRC2_DIMM or STR_REG
invoke MessageBox, 0, addr R, addr title_1,MB_OK 
invoke ExitProcess, 0
END START

[Аделинкка]

Хорошо.
Спасибо,Ulex.)

Я так понимаю,что все операторы (функции) начинаются почти такие же ,но все на чинается с fi.

[DiemonStar]

Я так понимаю,что все операторы (функции) начинаются почти такие же ,но все на чинается с fi.

Немного не так) C f начинаются все команды сопроцессора, а вот i обычно указывает на то, что операнды целочисленные (хотя есть исключения вроде finit)

[8Observer8]

Аделинкка, давайте разделим яблоки, используя сопроцессор. Итак, у нас 11 яблок. Их нужно разделить между нами поровну.

Отступление. Функции сопроцессора работают со стеком сопроцессора. То есть входные данные должны быть на своих местах в стеке. Мы должны эти входные данные подготовить, загрузив туда (в стек сопроцессора). Результат работы функций сохраняется в том же стеке.

Исходные данные:
Количество людей: 2 штуки
Количество яблок: 11 штук

Порядок действий:
- загружаем количество яблок на вершину стека, с помощью функции fild
- загружаем количество людей на вершину стека (число яблок при этом сдвигается от вершины на одну позицию, см. рисунок 1)

Рисунок 1:


Продолжаем порядок действий:
- итак, в стеке у нас: на нулевой позиции - количество людей, а на первой позиции количество яблок
- вызываем функцию fdiv, которая делит число на первой позиции в стеке сопроцессора на число в нулевой позиции в стеке сопроцессора.
- результат своей работы функция сохранила на вершине стека сопроцессора (см. рисунок 2).
- сохраним результат в переменной, которая объявлена с директивой dt (80-битная переменная), с помощью команды fstp
- сделаем преобразование содержимого 80-битной переменной result в последовательность ASCII символов (это для будущего вывода на экран), с помощью функции FpuFLtoA

Рисунок 2:

.386
.model flat, stdcall
option casemap:none

include c:\masm32\include\kernel32.inc
include c:\masm32\include\fpu.inc

includelib c:\masm32\lib\kernel32.lib
includelib c:\masm32\lib\fpu.lib

BSIZE    equ    20

.data
napples    dd    11
nmen       dd    2
result     dt    ?
buf        db    BSIZE dup(?)

.code
start:
    fild napples ; загружаем количество яблок на вершину стека
    fild nmen    ; загружаем количество людей на вершину стека
    fdiv         ; делим количество людей на количество яблок
    fstp result  ; сохраняем результат (вершину стека сопроцессора). Переменная result объявлена c
                 ; директивой dt (80 бит)

    invoke  FpuFLtoA, ADDR result, 10, \ ; перегоняем из 80-битной переменой result в буфер buf
                      ADDR buf, SRC1_REAL or SRC2_DIMM

    invoke ExitProcess, 0 ; завершаем процесс
end start

P.S. Функция FpuFLtoA используется для сохранения результата в буфере, чтобы потом вывести на экран содержимое этого буфера.

P.S.S. Вы видели, что данные мы загружали в стек сопроцессора с помощью fild. Здесь сокращение слов:
f - FPU (Floating Point Unit) - устройство для выполнения операций с плавающей точкой
i - integer - целое число
ld - load - загрузка
Таким образом, fild - это команда для загрузки целого числа в устройство, которое выполняет операции с плавающей точкой.

[Аделинкка]

Спасибо,вам всем)
У меня еще вопросик.А при работе с переменными надо писать [dword ptr]&(как в предыдущем коде?

[DiemonStar]

обычно, явное указание на размерность переменной необходимо когда размерности переменной и регистра не совпадают.

[8Observer8]

Аделинкка, вы ещё не все виды вывода результата на экран попробовали!

Обязательно попробуйте вывести результат работы вашей программы:
1. В консоль (функция WriteConsole)
2. В файл (функция WriteFile)
3. На элемент пользовательского интерфейса (например, в Edit)